- 從程式集開啟PyMOL
Open PyMol
- 載入pdb files, 可用指令模式或用工具列啟動
load 1L3M ( Use PyMOL Tcl/Tk GUI, File -> open -> /your_path/1L3M.pdb)
- 消去預先顯示的畫面
hide all
- 順著Z軸翻轉180度
rotate z, 180
- 設定背景顏色為白色
bg_color white
- 此1L3M.pdb為雙股螺旋DNA,每一股helix定義為一個chain,下兩個步驟為分別選擇chain A, chain B的方式
select chain-a, chain a
select chain-b, chain b
- chain a, chain b都用sticks表示,而且把bond的半徑縮小
show sticks, chain-a
show sticks, chain-b
set stick_radius = 0.13
- 定義chain a為藍色,chain b為綠色
color green, chain-b
color blue, chain-a
- 細分chain a的residues兩部份, 1-5 & 6-12,選擇方式如下,a15 & a612分別是選擇的object的名稱
select a15, resi 1-5
select a612,resi 6-12
- a15部分畫surface圖,a612部分畫sphere圖
show surface, a15
show sphere, a612
- a15的surface顏色為yellow, a612的sphere也是yellow
set surface_color,yellow, a15
set sphere_color,yellow, a612
- a15的透明度是0.33, a612的透明度是0.76
set transparency, 0.33, a15
set sphere_transparency,0.76,a612
- 手動增加兩個氫鍵,使用dist指令;其中///A/6/1H6的意思是/object/segment/chain/residues/atom的分類方式,在1L3M.pdb檔案中,只有一個object,一個segment,兩個chain(a/b),並選取residue 6的1H6,其餘三個選擇亦是如此;
dist hb1, ///A/6/1H6, ///B/19/O4
dist hb2, ///A/6/N1, ///B/19/H3
- 在這裡你會看到這個dist的指令其實是量距離的工具,但只要把label拿掉就像是一個hydrogen bond
hide labels
- 兩hbond的顏色分別定義為red for hb1, and orange for hb2
color red, hb1
color orange, hb2
- 最後把剛剛做出的兩組hbond修改一下,定義dash的radius是0.11(both for hb1,hb2),hb1的lenght是2,hb2沒有gap,你可以明顯看出hb1,hb2的差別.
set dash_radius, 0.11
set dash_length, 2,hb1
set dash_gap, 0, hb2
- 以chain B上的residue 18為中心放大,scale為-8
zoom ///B/18,-8
- 在輸入ray之前你看到hbond是細細的,ray指令執行後,會是類似stick的效果,可以自行比較.
你也可以在Tcl/Tk GUI視窗的command input area把上述的所有指令一次輸入,類似macro的功能(把下列指令全選,一次貼上即可)
load 1L3M.pdb
hide all
rotate z, 180
bg_color white
select chain-a, chain a
show sticks, chain-a
set stick_radius = 0.13
select chain-b, chain b
show sticks, chain-b
color green, chain-b
color blue, chain-a
select a15, resi 1-5
select a612,resi 6-12
show surface, a15
show sphere, a612
set surface_color,yellow, a15
set sphere_color,yellow, a612
set transparency, 0.33, a15
set sphere_transparency,0.76,a612
dist dist1, ///A/6/1H6, ///B/19/O4
dist dist2, ///A/6/N1, ///B/19/H3
hide labels
color red, dist1
color orange, dist2
set dash_length, 2,dist1
set dash_gap, 0, dist2
set dash_radius, 0.11
zoom ///B/18,-8
rayLast modified: 2004/04/27
